#!/bin/csh -f
#
# This script manages nonlocal installation of the uSystem software.
#

echo "The uSystem requires at least GNU C 2.5.8 for its installation."
echo "Your installation is currently running:"
gcc -v
while( 1 )
    echo -n "Enter valid compiler version {yes, no}: "
    set validgcc = ($<)
    switch ( $validgcc:q )
	case yes:
	    break
	case no:
	    exit
	default:
            echo "Invalid response: ${validgcc}"
            breaksw
    endsw
end

while ( 1 )
    echo -n "Enter cpu type {i386, mips, m68k, ns32k, vax, sparc, rs6000, pa}: "
    set cpu = ($<)
    switch ( $cpu:q )
        case i386:
	case mips:
	case m68k:
	case ns32k:
	case vax:
	case sparc:
	case rs6000:
	case pa:
            break
        default:
            echo "Invalid cpu: ${cpu}"
            breaksw
    endsw
end

while ( 1 )
    echo -n "Enter vendor name {apollo, dec, mips, sequent, sgi, sun, encore, ibm, hp}: "
    set vendor = ($<)
    switch ( $vendor:q )
        case apollo:
	    set os = bsd43
            break
	case dec:
	    switch ( $cpu:q )
		case mips:
		    set os = bsd43
	            break
		default:
		    set os = bsd43
	            break
	    endsw
            break
	case mips:
	    set os = bsd43
            break
        case sgi:
	    set os = irix
            break
        case sun:
	    set osverno = `uname -r`
	    switch ( $osverno:q )
		case 5.*:
		    set os = solaris
	            break
		default:
		    set os = bsd43
	            break
	    endsw
            break
        case sequent:
	    set os = bsd43
            break
	case encore:
	    set os = umax
            break
	case ibm:
	    set os = aix
            break
	case hp:
	    set os = ux
            break
        default:
            echo "Invalid vendor: ${vendor}"
            breaksw
    endsw
end

while ( 1 )
    echo -n "Enter documentation format - imperial (8.5in. x 11in.) or metric (A4) {imperial, metric}: "
    set pageformat = ($<)
    switch ( $pageformat:q )
        case imperial:
	case metric:
            break
        default:
            echo "Invalid page format: ${pageformat}"
            breaksw
    endsw
end

# build the system

./CONFIGURE ${vendor} ${os} ${cpu} ${pageformat}
