#!/bin/csh -f
#
# extract-one - get a list of stats from one sim file (*.sim)
#
set usage='usage: extract-one foo.sim[.gz] [foo.data]'
#
# Part of
#              The STARFISH Parallel file-system simulator
#        (Simulation Tool for Advanced Research in File Systems)
# 
#                               David Kotz
#                           Dartmouth College
#                              Version 3.0
#                              October 1996
#                          dfk@cs.dartmouth.edu

if ($#argv != 1 && $#argv != 2) then
	echo "$usage"
	exit 1
endif

onintr cleanup

set file=$1
if ($#argv > 1) then
	set data=$2
else
	# set "data" to be data file name
	if ($file:e == gz || $file:e == Z || $file:e == z) then
		set temp = $file:r
		set data = $temp:r.data
	else
		set data = $file:r.data
	endif
endif

set temp = $data:r
set trial = $temp:e   # get trial number from file name

set extracted=`simex -sim $file -noname -noheader Pattern CPFS IOPFS DISK_SORT RECORD_SIZE DISK_LAYOUT FILE_BLOCKS BLOCK_SIZE Nio Ncomp NO_OF_DISKS total tthruput`

echo $extracted $trial > $data

# did anything go wrong?
set tthruput=`colex 13 < $data`
if ($tthruput == 0) rm $data	# yes, delete the data file

cleanup:
